Forum Unity3D-France

Code : Tout sélectionner

// Unlit lightmapped reflective shader
// Diffuse texture (UV1)* Lightmap texture (UV2) + Reflection * ReflectionColor

Shader "MyCustomShaders/LightMap/Reflective" {
	Properties {
		_DiffuseColor ("Diffuse Color", Color) = (1, 1, 1, 1)
		_MainTex ("Base (RGB)", 2D) = "white" {}
		_LightMapTex ("Lightmap (RGB)", 2D) = "white" {}
		_Cube ("Reflection Cubemap", CUBE) = "_Skybox" {}
		_ReflectColor ("Reflection Color", Color) = (0.25, 0.25, 0.25, 1)
	}

	SubShader {
		Lighting Off //Pas de gestion de lumière

		Tags { "RenderType"="Opaque" }
		LOD 100

		CGPROGRAM
		#pragma surface surf NoLighting
		
		fixed4 LightingNoLighting (SurfaceOutput s, fixed3 lightDir, fixed atten)
		{
			fixed4 c;
			c.rgb = s.Albedo;
			c.a = s.Alpha;
			return c;
		}
		
		sampler2D _MainTex;
		sampler2D _LightMapTex;
		samplerCUBE _Cube;
		fixed4 _ReflectColor;
		fixed4 _DiffuseColor;
		
		struct Input {
		    half2 uv_MainTex : TEXCOORD0;
		    half2 uv_LightMapTex : TEXCOORD1;  //C'est ça marrez vous!  ;)
		    half3 worldRefl;
		    half3 viewDir;
		};
		
		void surf (Input IN, inout SurfaceOutput o) {
		    fixed4 tex = tex2D(_MainTex, IN.uv_MainTex);
		    fixed4 lm = tex2D(_LightMapTex, IN.uv_LightMapTex);
		    fixed3 reflcol = texCUBE (_Cube, IN.worldRefl);
		    fixed rim = 1.1 - dot (IN.viewDir, o.Normal);           //faux fresnel
		    o.Albedo = _DiffuseColor.rgb * tex.rgb * lm.rgb;      //Diffuse * couleur Diffuse * lightmap
		    o.Emission = reflcol.rgb * rim * _ReflectColor.rgb;   //couleur réflexion * réflexion * faux fresnel
		}
		ENDCG
	}
}

Code : Tout sélectionner

Input vert (appdata_full v) {
        	Input o;
        	o.uv_LightMapTex = v.texcoord1.xy;
        	return o;
        }

Code : Tout sélectionner

Input vert (inout appdata_full v) {
	Input o;
	o.uv_MainTex = v.texcoord.xy;
	o.uv_LightMapTex = v.texcoord1.xy;
	return o;
}

Code : Tout sélectionner

UNITY_INITIALIZE_OUTPUT(Input,o);

Code : Tout sélectionner

// Unlit lightmapped reflective shader
// Diffuse texture (UV1)* Lightmap texture (UV2) + Reflection * ReflectionColor

Shader "MyCustomShaders/LightMap/Reflective" {
	Properties {
		_DiffuseColor ("Diffuse Color", Color) = (1, 1, 1, 1)
		_MainTex ("Base (RGB)", 2D) = "white" {}
		_LightMapTex ("Lightmap (RGB)", 2D) = "white" {}
		_Cube ("Reflection Cubemap", CUBE) = "_Skybox" {}
		_ReflectColor ("Reflection Color", Color) = (0.25, 0.25, 0.25, 1)
		_Fresnel ("Fresnel Intensity", Float) = 1.0
	}

	SubShader {
		Lighting Off //Pas de gestion de lumière

		Tags { "RenderType"="Opaque" }
		LOD 100

		CGPROGRAM
		#pragma surface surf NoLighting
		#include "UnityCG.cginc"

		fixed4 LightingNoLighting (SurfaceOutput s, fixed3 lightDir, fixed atten)
		{
			fixed4 c;
			c.rgb = s.Albedo;
			c.a = s.Alpha;
			return c;
		}
	  
		sampler2D _MainTex;
		sampler2D _LightMapTex;
		samplerCUBE _Cube;
		fixed4 _ReflectColor;
		fixed4 _DiffuseColor;
		float _Fresnel;
	  
		struct Input {
			half2 uv_MainTex : TEXCOORD0;
			half2 uv2_LightMapTex : TEXCOORD1; //Faut mettre un petit 2 après uv même si on précise bien TEXCOORD1. Stupide.
			half3 worldRefl;
			half3 viewDir;
		};
	  
		void surf (Input IN, inout SurfaceOutput o) {
			fixed4 tex = tex2D(_MainTex, IN.uv_MainTex);
			fixed4 lm = tex2D(_LightMapTex, IN.uv2_LightMapTex);
			fixed3 reflcol = texCUBE (_Cube, IN.worldRefl);
			fixed rim = _Fresnel - dot (IN.viewDir, o.Normal);
			o.Albedo = _DiffuseColor.rgb * tex.rgb * lm.rgb;
			o.Emission = reflcol.rgb * rim * _ReflectColor.rgb;
		}

		ENDCG
	}
}